'
   '  ******************************************************
   '  *                                                    *
   '  *  ATAハード・ディスク ディレクトリ 表示プログラム   *
   '  *                                                    *
   '  *     AVR is using ATmega128                         *
   '  *     Basic Compiler is BASCOM-AVR                   *
   '  *        Copyright By O-Family   2008. 5. 2          *
   '  ******************************************************
   '
   '     Ver 01.01  初回公開バージョン
   '
   '
$regfile = "M128def.dat"
$crystal = 16000000
   '
$hwstack = 128
$swstack = 128
$framesize = 128
   '
   Dim Temp1 As Byte                                        '汎用テンポラリ変数 Byte型 No.1
   Dim Tempstr As String * 15                               '汎用テンポラリ変数 String型
   '
   Config Date = Ymd , Separator = /                        '年/月/日 に変更。
   '
   '
$include "Config_HardDisk_M128_JP.bas"                      'ATAハード・ディスクのピン設定プログラムを組み込む。
   '
   If Gbdriveerror <> 0 Then Goto Driveerr                  'If 初期化でエラーが発生した? Then
   '
$include "CONFIG_AVR-DOS_JP.bas"                            'AVR-DOSの設定プログラムを組み込む。
   '
   Print "Initialize Ok!" : Print                           '初期化終了メッセージを出力。
   '
   Temp1 = Initfilesystem(1)                                'ファイル・システムを初期化する。
   If Temp1 > 0 Then Goto Avrdoserr                         'If AVR-DOSエラーが発生した? Then
   '
   '
   '  * ディレクトリを表示 *
   '
   '
   Tempstr = Dir( "*.*")                                    '最初のディレクトリを読み込む。（すべてのファイル）
   While Len(tempstr) > 0                                   'ファイル名が無くなるまで繰り返し。
      Print Tempstr ; "  " ;                                'ファイル名を表示。
      Print Filedate() ; " " ;                              'ファイルの日付を表示。
      Print Filetime() ; " " ;                              'ファイルの時間を表示。
      Print Filelen() ; "byte " ;                           'ファイルのレングスを表示。
      Print Hex(getattr())                                  'ファイルの属性を表示。
      Tempstr = Dir()                                       '次のファイル名を読み込む。
   Wend
   '
   '
   Print
   Print "End!"                                             '表示終了メッセージを出力。
   Print
   End
   '
   '
   '
Driveerr:
   Print "Drive Error!"
   End
   '
   '
Avrdoserr:
   Print "AVR-DOS Error! " ; Temp1
   End