/*
    Nokia6100用画像リサイズ ImageJマクロ rev1.1
    ImageJ 1.42oで動作確認

    http://ekousaku.web.fc2.com/
    趣味の電子工作の部屋ｂｙすん
    2009.9.12

   --- Nokia6100　Resize.txt 使用方法 ---

１．ImageJをインストールしてください。
２．このファイルをImageJのインストールフォルダに
    あるmacros\toolsetsにコピーしてください。
    通常はC:\Program Files\ImageJにあるはずです。
３．ImageJを実行してください。
４．>>ボタンをクリックするとNokia6100 Resizeが
    表示されるので選択します。
５．赤いsrボタンと赤いfrボタンが追加されます。
    srボタン：シングルファイルリサイズ用
    frボタン：フォルダリザイズ用（フォルダ内のファイル）１階層のみ

６s．srボタンをクリックするとSelect a File画面が
    表示されます。
７s．１つ画像ファイルを選択し開くボタンをクリックすると
    自動的にtw,thサイズにリサイズしoutDirフォルダに
    ファイル保存します。

６f．frボタンをクリックするとSelect Input Folder画面が
    表示されます。
７f．フォルダを選択しSelectボタンをクリックすると
    フォルダ内のファイルすべて（１階層のみ）を
    自動的にtw,thサイズにリサイズしoutDirフォルダに
　　ファイル保存します。

※tw, th, outDir, fileformat, posi, bwは各パラメータは
  以下のソース内★設定★を参照して変更をおこなってください。

※このファイルを変更した場合は、手順４で別のものを
  選んでから、もう一度このNokia6100 Resizeを
  選びなおしてください。
*/

macro 'Unused Tool -' {}
macro 'Unused Tool -' {}

//単ファイル
macro "Nokia6100 Resize Tool (Single file Resize) Action Tool - Cf00fT1e12sTbe12r"
{
    //ファイル選択
    path = File.openDialog("Select a File");
    open(path); // open the file
    name = File.getName(path);

    Nokia6100Resize(name);
}
macro 'Unused Tool -' {}

//複数ファイル
macro "Nokia6100 Resize Tool (Folder files Resize) Action Tool - Cf00fT1e12fTbe12r"
{
    CurDir = getDirectory("Select Input Folder");
    list = getFileList(CurDir);

    for (i=0; i<list.length; i++) {
        showProgress(i+1, list.length);
        open(CurDir+list[i]);
        name = list[i];

        Nokia6100Resize(name);
    }
}

function Nokia6100Resize(name)
{
//-----------------------------------------
// ★設定★ここから
    fileformat = 2 ;//出力ファイルフォーマット
                    //1:RAW(RGB24) , 2:Bitmap

    tw = 130 ; //リサイズ後の画像幅（ピクセル）
    th = 130 ; //リサイズ後の画像高さ（ピクセル）

    posi = 2 ; //余白の位置（横長か縦長によって異なります）
               //1:横長＝上と下、縦長＝左と右
               //2:横長＝下のみ、縦長＝右のみ
               //3:横長＝上のみ、縦長＝左のみ

    bw = 0 ; //余白の色
             // 1:白
             // 0:黒

    outDir = "C:\\Temp\\" ; //画像出力フォルダ
                            //最後に\\を付けてください
// ★設定★ここまで
//-----------------------------------------

    setTool(0);//アイコン戻す

   sname = my_nameWithoutExtension(name);

    //print("name="+name);
    //print("sname="+sname);

    w = getWidth();//幅
    h = getHeight();//高さ

    //サイズ調整
    if(w >= h){
        nw = tw;
        nh = tw * h / w;
    }
    else{
        nw = th * w / h;
        nh = th;
    }

    //スケール実行
    param_s = "x=- y=- width=" + nw + " height=" + nh
            + " interpolation=Bilinear create title=" + sname;
    run("Scale...", param_s);

    //ターゲットサイズにする
    if(posi==1) strposi = "Center";
    else{
        if(w >= h){
            if(posi==2) strposi = "Top-Center";
            else if(posi==3) strposi = "Bottom-Center";
        }
        else{
            if(posi==2) strposi = "Center-Left";
            else if(posi==3) strposi = "Center-Right";
        }
    }
    if(bw==0) strbw = "zero";
    else strbw = "";
    param_c = "width=" + tw + " height=" + th 
            + " position=" + strposi + " " + strbw;
    run("Canvas Size...", param_c);

    //元画像閉じる
    selectWindow(name);
    close();

    //出力フォルダ確認、無ければ作成
    if(!File.exists(outDir)){
        File.makeDirectory(outDir);
        if(!File.exists(outDir)){
            exit("Unable to create directory");
        }
    }

    //リサイズ画像保存
    selectWindow(sname);

    if(fileformat==1){
        outfile = outDir + sname + ".raw";
        saveAs("Raw Data", outfile);
    }
    else if(fileformat==2){
        outfile = outDir + sname + ".bmp";
        saveAs("BMP", outfile);
    }

    close();
//    open(outfile);
}

//拡張子を取り除く
function my_nameWithoutExtension(str){
    n = lastIndexOf(str, ".");

    if(n>=0)    rstr = substring(str, 0, n);//"."有った
    else rstr = str;//"."無し

    return rstr;
}