$programmer = 16                                            'USBprog Programmer/ AVR ISP mkII (Atmel)

   '
   '  ************************************************
   '  *  2.42インチ 128x64ドット 有機ELディスプレイ  *
   '  *      OLED (SSD1309)  テスト・プログラム      *
   '  *  　  (USI用)     O-Family   2022. 7. 9       *
   '  ************************************************
   '

$regfile = "ATtiny85.DAT"                                   '使用するAVRを設定。
$crystal = 1000000                                          'AVRクロックを設定。
   '
$hwstack = 64                                               'ハードウェア・スタックの容量を設定。
$swstack = 10                                               'ソフトウェア・スタックの容量を設定。
$framesize = 24                                             'フレーム領域の容量を設定。

   '
   '  OLEDコントローラ[SSD1309]の設定 ([I2C,USI]で接続) *
   '
   Const I2c_select = 1                                     'I2Cインターフェイスの選択。(0:ソフトウェアI2C , 1:ハードウェアUSI)

#if I2c_select = 0                                          'ソフトウェアI2Cの場合。
   Config Scl = Portb.2                                     'I2CバスのSCLラインを接続するポートピンを設定。
   Config Sda = Portb.0                                     'I2CバスのSDAラインを接続するポートピンを設定。
   Config I2cdelay = 1                                      'SCLのクロック周波数。
   I2cinit                                                  'I2CバスのSCL,SDAラインを初期化する。
#else                                                       'ハードウェアUSIの場合。
   Config Usi = Twimaster , Mode = Fast                     'USIマスターの設定。I2Cバスのクロック = 400KHz
   I2cinit                                                  'I2CバスのSCL,SDAラインを初期化する。
#endif
   '
   Dim _contrast As Byte                                    'OLEDのコントラスト設定値。[0-255]
   Const Ssd1309_sa0 = 0                                    'SSD1309のスレーブ・アドレス。(0:SA0=[L] 78H , 1:SA0=[H] 7AH)
   Const Ssd1309_rotate = 0                                 '画面の回転。(接続ケーブルが左側=[0], 右側=[1])
   $lib "glcdSSD1309-I2C_V2.lib"                            'SSD1309-I2Cの機能追加版ライブラリを組み込む。
   Config Graphlcd = Custom , Cols = 128 , Rows = 64 , Lcdname = "SSD1309"       'OLEDの設定。
   Cls                                                      'OLEDの表示をすべて消去。

'--------------------------------------------------------------------------------------------------

   '
   '  * OLED表示テストプログラム *
   '
   Do
      Setfont Font8x8tt                                     'フォントを設定する。
      Lcdat 1 , 1 , "SSD1309 2.42{034} OLED"                '通常の文字表示。
      Lcdat 2 , 8 , "128x64dots SPI,I2C"                    '通常の文字表示。
      Lcdat 6 , 1 , " ABCDefg012345678 " , 2                '実線のアンダーライン。
      Lcdat 8 , 1 , " ABCDefg012345678 " , 3                '点線のアンダーライン。
      Setfont Font8x8                                       'フォントを設定する。
      Lcdat 4 , 1 , "[BASCOM-AVR MCS]" , 1                  '反転表示。
      Wait 3

      Glcdcmd &HA7                                          '画面の表示設定。 [A7:反転]
      Wait 3
      Glcdcmd &HA6                                          '画面の表示設定。 [A6:通常]
      Wait 3

      _contrast = 0 : Glcdcmd &H81                          'OLEDのコントラスト設定。 [0:暗い - 255:明るい]
      Wait 3
      _contrast = 255 : Glcdcmd &H81                        'OLEDのコントラスト設定。 [0:暗い - 255:明るい]
      Wait 3

      Glcdcmd &HAE                                          '表示のON/OFF。 [AE:OFF(スリープ・モード)]
      Wait 3
      Glcdcmd &HAF                                          '表示のON/OFF。 [AF:ON(通常モード)]
      Wait 3

      Showpic 0 , 0 , Plaatje                               'BGFファイル（BMPを圧縮した画像）を描画する。
      Wait 3
      Cls
   Loop

   End

   '
   '  * フォント・データ *
   '
$include "font8x8TT.font"                                   'フォント・ファイルを組み込む。
$include "font8x8.font"
   '
   '  * BGFファイル・データ *
   '
Plaatje:
   $bgf "ks108.bgf"                                         'BGFファイル。（BMPを圧縮した画像)