$programmer = 26                                            'MCS UPDI programmer

   '
   '  ********************************************
   '  *  2.42インチ 128x64ドット OLED (SSD1309)  *
   '  *  [I2C]で2台接続するプログラム (XTINY用)  *
   '  *            O-Family   2022. 7. 7         *
   '  ********************************************
   '

$regfile = "mx4809.dat"                                     '使用するAVRを設定。
$crystal = 20000000                                         'AVRクロックを設定。
   '
$hwstack = 64                                               'ハードウェア・スタックの容量を設定。
$swstack = 10                                               'ソフトウェア・スタックの容量を設定。
$framesize = 24                                             'フレーム領域の容量を設定。

   Config Sysclock = 20mhz , Prescale = 1                   'システムクロックの設定。

   '
   '  OLEDコントローラ[SSD1309]の設定 ([I2C]で2台接続) (XTINY用) *
   '
   Const I2c_select = 1                                     'I2Cインターフェイスの選択。(0:ソフトウェアI2C , 1:ハードウェアTWI)
   '
   #if I2c_select = 0                                       'ソフトウェアI2Cの場合。
      Const Twi_adr = Twi0_ctrla : Const Twi_ch = 1         '[ライブラリ内のダミー]
      $forcesofti2c                                         'ソフトウェアI2C/TWIライブラリを強制的に使用する。
      $lib "i2c.lbx"                                        'ソフトウェアI2C用のライブラリを上書きする。
      Config I2cdelay = 1                                   'SCLのクロック周波数 = 約260KHz。(AVRクロック20MHz時) (*最大400KHz)
      Config Scl = Porta.5                                  'I2CバスのSCLラインを接続するポートピンを設定。
      Config Sda = Porta.6                                  'I2CバスのSDAラインを接続するポートピンを設定。
      I2cinit                                               'I2CバスのSCL,SDAラインを初期化する。
   #else                                                    'ハードウェアTWIの場合。
      Dim Twi_start As Byte                                 'TWIライブラリで使用する変数。
      Const Twi_adr = Twi0_ctrla                            'TWIのポート。TWI_ADR = TWI0_CTRLA:(TWI0)
      Const Twi_ch = 1                                      'TWIのチャンネル。TWI_CH = 1:(TWI0), 2:(TWI1)
      Config Twi0 = 400000                                  'TWIバスのクロック = 400KHz (*最大400KHz)
      I2cinit                                               'TWIバスのSCL,SDAラインを初期化する。
   #endif
   '
   Dim _contrast As Byte                                    'OLEDのコントラスト設定値。[0-255]
   Dim I2c_addr As Byte                                     'I2Cのスレーブ・アドレス選択。[&H78 or &H7A]
   Reset Porta.7                                            'OLED(SSD1309)の[RES]ピンを[L]にする。
   Config Porta.7 = Output                                  'OLED(SSD1309)の[RES]ピンの接続ポートを出力に設定する。
   Waitms 1                                                 'OLEDのリセットパルスの[L]期間。
   Config Porta.7 = Input                                   'OLED(SSD1309)の[RES]ピンの接続ポートを入力に設定する。(オープン・ドレイン)
   Waitms 10                                                'OLEDの起動待ち時間。
   '
   Const Ssd1309_rotate = 0                                 '画面の回転。(接続ケーブルが左側=[0], 右側=[1])
   $lib "glcdSSD1309-I2C_V2x2.lib"                          'SSD1309-I2Cの2台用の機能追加版ライブラリを組み込む。
   Config Graphlcd = Custom , Cols = 128 , Rows = 64 , Lcdname = "SSD1309"       'OLEDの設定。
   '
   I2c_addr = &H78                                          '1台目のOLEDを選択する。
   Cls                                                      'OLEDの表示をすべて消去。
   I2c_addr = &H7A                                          '2台目のOLEDを選択する。
   Cls                                                      'OLEDの表示をすべて消去。

'--------------------------------------------------------------------------------------------------

   '
   '  * OLED表示テストプログラム *
   '

   Setfont Font8x8tt                                        'フォントを設定する。
   '
   '  * 1台目の表示 *
   '
   I2c_addr = &H78                                          '1台目のOLEDを選択する。
   Lcdat 1 , 1 , "SSD1309 2.42{034} OLED"                   '通常の文字表示。
   Lcdat 2 , 8 , "128x64dots SPI,I2C"                       '通常の文字表示。
   Lcdat 4 , 2 , "Multiple Connections" , 1                 '反転表示。
   Lcdat 6 , 9 , " < I2C Unit 1 > " , 2                     '実線のアンダーライン。
   Lcdat 8 , 1 , "  Address = [78]  " , 3                   '点線のアンダーライン。

   '
   '  * 2台目の表示 *
   '
   I2c_addr = &H7A                                          '2台目のOLEDを選択する。
   Lcdat 1 , 1 , "SSD1309 2.42{034} OLED"                   '通常の文字表示。
   Lcdat 2 , 8 , "128x64dots SPI,I2C"                       '通常の文字表示。
   Lcdat 4 , 2 , "Multiple Connections" , 1                 '反転表示。
   Lcdat 6 , 9 , " < I2C Unit 2 > " , 2                     '実線のアンダーライン。
   Lcdat 8 , 1 , "  Address = [7A]  " , 3                   '点線のアンダーライン。

   End

   '
   '  * フォント・データ *
   '
$include "font8x8TT.font"                                   'フォント・ファイルを組み込む。