Sub 段落番号置換()
' 段落番号置換マクロ
' 作成日 03/08/23 作成者 岡田
'------------------------------------------------------------------------------
'  文書中の【＃＃＃＃】を検索し、＃＃＃＃を連番に置き換えます。
'  ＃＃＃＃は任意の４桁の数字です。
'------------------------------------------------------------------------------
    Dim AddStr
    Dim Num
    Dim Flg_Conv
    Dim Msg_Title
    Msg_Title = "おしらせ"
    Num = 1
    Flg_Conv = 0
    Set myRange = ActiveDocument.Range()
    With myRange.Find
        .ClearFormatting
        .Text = "【^#^#^#^#】"
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindStop
        .Format = False
        .MatchCase = False
        .MatchWholeWord = True
        .MatchByte = False
        .MatchAllWordForms = False
        .MatchSoundsLike = False
        .MatchWildcards = False
        .MatchFuzzy = False
        Do While .Execute = True
            With .Parent
                Flg_Conv = 1
                .Delete
                AddStr = "【" + StrConv(Format(Num, "0000"), vbWide) + "】"
                .Font.Reset
                .InsertAfter (AddStr)
                .Move
            End With
            Num = Num + 1
        Loop
    End With
If Flg_Conv = 1 Then
    MsgBox StrConv(Num - 1, vbWide) + "個の段落番号を置換しました。", , Msg_Title
Else
    MsgBox "段落番号が見あたりません。", , Msg_Title
End If
End Sub